日付ファイルを毎回リネームしたい (DOSプロンプト活用相談室LOG)

626.	日付ファイルを毎回リネームしたい 2004年07月14日(水) 19時11分

ori

毎日作成されるファイルがあるのですが
これが　（例）txt20040701.doc
というように日付が毎回付きます
これを毎回リネームして、txt20040701.doc　から　txt20040701.doc_endと言う感じにしたいのです

renameコマンドを使えばいいのですが
毎回入力しなくてはいけないし、ある実行batに組み込みたいのです
どうすればいいのでしょうか？
（毎回、ファイル名に日付が付くのでどうして良いかわかりません）
よろしくお願いいたします

627.	Re:日付ファイルを毎回リネームしたい 2004年07月14日(水) 19時27分

じゃく

OSは何ですか？
リネームしたいディレクトリに入っている.doc のファイルは
日付のファイル以外に有りますか？
単に、
ren *.doc *.doc_end
ではダメですか？

628.	Re2:日付ファイルを毎回リネームしたい 2004年07月14日(水) 19時38分

ori

＞OSは何ですか？
linuxからftpで持ってきたファイルになります

（linuxからWindowsのdosでFTPより持ってきている、、、、）
renameコマンドを発行するのはWindosのdosです
＞リネームしたいディレクトリに入っている.doc のファイルは
＞日付のファイル以外に有りますか？
日付のほかにもあると思います
同じ拡張子があるファイルだと問題があっては困るので、、、

よろしくお願いします

629.	Re3:日付ファイルを毎回リネームしたい 2004年07月14日(水) 19時43分

じゃく

＞＞OSは何ですか？

＞renameコマンドを発行するのはWindosのdosです

そのWindowsのバージョンを聞いているのです。
98 / Me / NT / 2000 / XP どれでしょうか？

630.	Re4:日付ファイルを毎回リネームしたい 2004年07月14日(水) 19時44分

ori

＞＞＞OSは何ですか？
すみません

windows2000　serverになります

631.	Re5:日付ファイルを毎回リネームしたい 2004年07月14日(水) 19時54分

じゃく

＞毎日作成されるファイルがあるのですが
＞これが　（例）txt20040701.doc
＞というように日付が毎回付きます
＞これを毎回リネームして、txt20040701.doc　から　txt20040701.doc_endと言う感じにしたいのです

＞windows2000　serverになります

2000なら%date%という環境変数を使って、実行時の日付を取得できます。以下のようになります。

set yyyymmdd=%date:~-10%
set yyyymmdd=%yyyymmdd:/=%
ren txt%yyyymmdd%.doc txt%yyyymmdd%.doc_end

632.	Re5:日付ファイルを毎回リネームしたい 2004年07月14日(水) 19時54分

ori

追伸：
やはり同じディレクトリには同じ拡張子があります。
唯一違うのはファイル名の間に日付が入っています。

ただ、ファイル名の終わりに_endという名前を付けるだけということなんですが、、、、、

633.	Re6:日付ファイルを毎回リネームしたい 2004年07月14日(水) 19時55分

ori

ありがとうございます
やってみますね！　＾０＾

634.	Re6:日付ファイルを毎回リネームしたい 2004年07月14日(水) 20時01分

ori

ちなみに

＞set yyyymmdd=%date:~-10%
　　　　　　　　　　　　↑
~-10%はどのような意味を持つのでしょうか？
良ければ教えてください

635.	Re7:日付ファイルを毎回リネームしたい 2004年07月14日(水) 20時08分

じゃく

＞ちなみに
＞
＞＞set yyyymmdd=%date:~-10%
＞　　　　　　　　　　　　↑
＞~-10%はどのような意味を持つのでしょうか？
＞良ければ教えてください

環境変数 %date% の末尾から10文字を取り出す文法です。
set /? で詳細をご確認下さい。
2000 の場合 echo %date% とすると
水 2004/07/14
と表示されるので先頭の曜日を取り除くために入れています。

636.	Re8:日付ファイルを毎回リネームしたい 2004年07月14日(水) 20時55分

ori

もうひとつ
ftp>の状態でもリネームすることはできますか？

637.	Re9:日付ファイルを毎回リネームしたい 2004年07月14日(水) 21時06分

じゃく

＞毎日作成されるファイルがあるのですが
＞これが　（例）txt20040701.doc
＞というように日付が毎回付きます
＞これを毎回リネームして、txt20040701.doc　から　txt20040701.doc_endと言う感じにしたいのです
＞
＞renameコマンドを使えばいいのですが
＞毎回入力しなくてはいけないし、ある実行batに組み込みたいのです
＞どうすればいいのでしょうか？
＞（毎回、ファイル名に日付が付くのでどうして良いかわかりません）
＞よろしくお願いいたします
＞

＞もうひとつ
＞ftp>の状態でもリネームすることはできますか？
＞
もしかして、FTPに接続している相手(Linux）サーバ上の
ファイルを rename をすることを考えているのですか？
この掲示板はDOSプロンプト活用相談室なので
DOS上のバッチの質問だと思って回答していたのですが、
それだと考え方を変える必要があります。

どのような手順でどこのファイルを(windows上のファイルか
linux上のファイルか）をどのように変更したいのかを
もう少し詳しくまとめて発言してください。

細切れに質問されると相談がどんどん長くなってしまいます。

638.	Re10:日付ファイルを毎回リネームしたい 2004年07月14日(水) 23時34分

ori

ご返信有難うございます
ちょっと私の勘違いもあるみたいでした
AというサーバーがありBという（win2000）のサーバーがあります
Aでできたファイル txt20040714.txtをBで受け取ります
Bが受け取ったとき、Aのサーバーのファイルの名前をtxt20040714.txt_endと変えたいのです
（ファイル名の日付はoracleから取得しているみたいです）

それと何かの影響で同一日に前日の転送もあるのです

echo open IPアドレス > ftp%table%_get.txt
echo ディレクトリー　>> ftp%table%_get.txt
type %work%\ftpcmd_%tablel%.txt >> ftp%table%_get.txt
echo y
echo bye

byeの前に　echo ren ファイル名.txt 変更後のファイル名.txt
を追加して名前が変更になるのでしょうか？

文章が下手で申し訳ありません

639.	Re10:日付ファイルを毎回リネームしたい 2004年07月14日(水) 23時41分

ori

追伸
実行はwin2000の　batファイルから実行

Ａサーバーはwin2000　Bサーバーはwin2000

念のため

AサーバーはLINUX　　Bサーバーはwin2000　の2パターンで....

FTPを使う際　LINUXとWINとでは全然違ってくるのですか?

FTPは使ったこと無いので、、、、かなり混乱しています

重ね重ね宜しくです。。、、mm__mm

643.	Re11:日付ファイルを毎回リネームしたい 2004年07月15日(木) 09時24分

じゃく

おはようございます。

＞AというサーバーがありBという（win2000）のサーバーがあります
＞Aでできたファイル txt20040714.txtをBで受け取ります
＞Bが受け取ったとき、Aのサーバーのファイルの名前をtxt20040714.txt_endと変えたいのです

つまりFTP -s で自動実行するコマンドをバッチで作成する際に、取得先のFTPサーバにある取得済みのファイルのファイル名を
変更したいと言うことですね。

＞それと何かの影響で同一日に前日の転送もあるのです

これは、ファイル名が実行日の前日である事があるという
意味ですか？
前日の日付を求めるのは少々ややこしいですよ。

＞echo open IPアドレス > ftp%table%_get.txt
＞echo ディレクトリー　>> ftp%table%_get.txt
＞type %work%\ftpcmd_%tablel%.txt >> ftp%table%_get.txt
＞echo y >> ftp%table%_get.txt
＞echo bye　>> ftp%table%_get.txt
＞
＞byeの前に　echo ren ファイル名.txt 変更後のファイル名.txt
＞を追加して名前が変更になるのでしょうか？

変更されます。最終的に ftp -s:ftp%table%_get.txt として
自動実行する予定なのですよね。
余談ですが、%work%\ftpcmd_%tablel%.txtに取得するファイル名が
入っているのならこのファイルを作る際にどうして rename も
コマンドとして作ってしまわないのか不思議です。

644.	Re11:日付ファイルを毎回リネームしたい 2004年07月15日(木) 09時27分

じゃく

＞Ａサーバーはwin2000　Bサーバーはwin2000
＞AサーバーはLINUX　　Bサーバーはwin2000　の2パターンで....
＞FTPを使う際　LINUXとWINとでは全然違ってくるのですか?

dir や ls の返すフォーマットが異なるかもしれませんが。使えるコマンドはほとんど同じと考えていいと思います。

645.	Re12:日付ファイルを毎回リネームしたい 2004年07月15日(木) 12時09分

ori

何回もレスありがとうございます
＞おはようございます。
＞つまりFTP -s で自動実行するコマンドをバッチで作成する際に、取得先のFTPサーバにある取得済みのファイルのファイル名を
＞変更したいと言うことですね。

はい　そのとうりです^0^

＞これは、ファイル名が実行日の前日である事があるという
＞意味ですか？
＞前日の日付を求めるのは少々ややこしいですよ。

可能性もあるとのことなんです

echo ren %tablel%.txt %tablel%.txt_end >> ftp%table%_get.txt

↑これでうまくいきますでしょうか？

＞変更されます。最終的に ftp -s:ftp%table%_get.txt として
＞自動実行する予定なのですよね。
＞余談ですが、%work%\ftpcmd_%tablel%.txtに取得するファイル名が
＞入っているのならこのファイルを作る際にどうして rename も
＞コマンドとして作ってしまわないのか不思議です。
出来れば伝授してください

初心者が行っていますのでまだちんぷんかんぷんなんです　^^;

%work%
ftpcmd
%tablel%

%がつくと良く解らなくなります　^^;

646.	Re13:日付ファイルを毎回リネームしたい 2004年07月15日(木) 13時38分

じゃく

＞＞前日の日付を求めるのは少々ややこしいですよ。
＞
＞可能性もあるとのことなんです
じゃぁ、いまは考えないことにします。

＞echo ren %tablel%.txt %tablel%.txt_end >> ftp%table%_get.txt
＞
＞↑これでうまくいきますでしょうか？
環境変数 table には日付の文字列 (例: 20040701)が入っているのでしょうか？

＞
＞＞変更されます。最終的に ftp -s:ftp%table%_get.txt として
＞＞自動実行する予定なのですよね。
＞＞余談ですが、%work%\ftpcmd_%tablel%.txtに取得するファイル名が
＞＞入っているのならこのファイルを作る際にどうして rename も
＞＞コマンドとして作ってしまわないのか不思議です。
＞出来れば伝授してください
＞
＞初心者が行っていますのでまだちんぷんかんぷんなんです　^^;
＞
＞
＞%work%
＞ftpcmd
＞%tablel%
＞
＞%がつくと良く解らなくなります　^^;

%work% は環境変数 work の中身に文字列を置き換えるという意味です。
例えばバッチで
echo off
set abc=test
echo 変数の値は... %abc%
とすると
変数の値は... test
と表示されます。

とりあえず、rename を入れて改造しようとしているバッチを
抜粋せずに示すことはできませんか？

647.	Re14:日付ファイルを毎回リネームしたい 2004年07月15日(木) 14時32分

ori

環境変数には日付の文字列は入っています。

バッチをのせましたのでよろしくお願いいたします。
実際にリネームしたいところに＊＊＊＊でコメントしています

@echo on

date /t
time /t

set DRIVE=E:
set BASE_DIR=%DRIVE%\tako

set SYS_NAME=model1

set abc_DIR=%BASE_DIR%\abc\%SYS_NAME%

set BATCH_LOG=%abc_DIR%\bat\model1_mbko.log
set BATCH_ERR=%abc_DIR%\bat\model1_mbko.err

date /t >> %BATCH_LOG%
time /t >> %BATCH_LOG%

date /t >>%BATCH_ERR%
time /t >>%BATCH_ERR%

set DATA_DIR=%BASE_DIR%\data\%SYS_NAME%
set RESOURCE_DIR=%BASE_DIR%\resource\%SYS_NAME%

set BACK_DIR=%DATA_DIR%\back
set FILED_LIST_DIR=%RESOURCE_DIR%\field_list
set CTRL_LIST_DIR=%RESOURCE_DIR%\ctrl_list
set RES_SQL_DIR=%RESOURCE_DIR%\sql_list
set SQLLOAD_DIR=%abc_DIR%\ctl
set WORK_DIR=%abc_DIR%\work
set LOG_DIR=%abc_DIR%\logs

set GZIP_EX=%BASE_DIR%\abc\gzip-2.3.6-bin\bin\gzip.exe
set LOADSTRING=%BASE_DIR%\abc\mybin\loader.exe
set SUBSTRING=%BASE_DIR%\abc\mybin\suing.exe

rem set DB_CONNECT=ori/7777@orcl
set DB_CONNECT=model1/pwmodel1@ori_db1
set COMMIT_ROW=400000

set TABLE_BASE=NS_NDS

%DRIVE%

cd %WORK_DIR%

rem oracleより、前日の日を取得するＳＱＬを作成。

echo %DB_CONNECT%                                        > %TABLE_BASE%_select_script.sql
echo set echo off                                       >> %TABLE_BASE%_select_script.sql
echo set heading off                                    >> %TABLE_BASE%_select_script.sql
echo set termout off                                    >> %TABLE_BASE%_select_script.sql
echo set pause off                                      >> %TABLE_BASE%_select_script.sql
echo set pagesize 0                                     >> %TABLE_BASE%_select_script.sql
echo set linesize 80                                    >> %TABLE_BASE%_select_script.sql
echo set feedback off                                   >> %TABLE_BASE%_select_script.sql

echo SPOOL %WORK_DIR%\ftpcmd_%TABLE_BASE%_get_doc.txt   >> %TABLE_BASE%_select_script.sql
type %RES_SQL_DIR%\%TABLE_BASE%_select_get_doc.txt      >> %TABLE_BASE%_select_script.sql
echo SPOOL OFF;                                         >> %TABLE_BASE%_select_script.sql
echo SPOOL %WORK_DIR%\ftpcmd_%TABLE_BASE%_get_txt.txt   >> %TABLE_BASE%_select_script.sql
type %RES_SQL_DIR%\%TABLE_BASE%_select_get_txt.txt      >> %TABLE_BASE%_select_script.sql
echo SPOOL OFF;                                         >> %TABLE_BASE%_select_script.sql
echo ;                                                  >> %TABLE_BASE%_select_script.sql
echo exit;                                              >> %TABLE_BASE%_select_script.sql

rem oracleより、前日の日を取得。

sqlplus @%WORK_DIR%\%TABLE_BASE%_select_script.sql

rem ファイルget ftpコマンド作成
rem 先頭３行は、リダイレクトをわざとつめている。

echo open 00.000.0.00>                               ftp_%TABLE_BASE%_get.txt
echo ori>>                                        ftp_%TABLE_BASE%_get.txt
echo pwori>>                                      ftp_%TABLE_BASE%_get.txt
echo ls                                          >>  ftp_%TABLE_BASE%_get.txt
echo bin                                         >>  ftp_%TABLE_BASE%_get.txt
type %WORK_DIR%\ftpcmd_%TABLE_BASE%_get_doc.txt  >>  ftp_%TABLE_BASE%_get.txt
echo y                                           >>  ftp_%TABLE_BASE%_get.txt
type %WORK_DIR%\ftpcmd_%TABLE_BASE%_get_txt.txt  >>  ftp_%TABLE_BASE%_get.txt
echo y                                           >>  ftp_%TABLE_BASE%_get.txt
echo ren %TABLE_BASE.doc.Z %TABLE_BASE.doc.Z_end >>  ftp_%TABLE_BASE%_get.txt
echo ren %TABLE_BASE.txt %TABLE_BASE.txt_end     >>  ftp_%TABLE_BASE%_get.txt
echo bye                                         >>  ftp_%TABLE_BASE%_get.txt

rem ファイルget

******************************************************************
* ↑　ここにリネームの記述を入れたのですが、、、、あっているのかな？
**********

cd %SQLLOAD_DIR%
～～～～

648.	Re15:日付ファイルを毎回リネームしたい 2004年07月15日(木) 15時08分

じゃく

長くなりますが、ご容赦願います。＞ＡＬＬ

＞環境変数には日付の文字列は入っています。

本当ですか？

＞set TABLE_BASE=NS_NDS

（中略）

＞echo SPOOL %WORK_DIR%\ftpcmd_%TABLE_BASE%_get_doc.txt   >> %TABLE_BASE%_select_script.sql
＞type %RES_SQL_DIR%\%TABLE_BASE%_select_get_doc.txt      >> %TABLE_BASE%_select_script.sql
＞echo SPOOL OFF;                                         >> %TABLE_BASE%_select_script.sql
＞echo SPOOL %WORK_DIR%\ftpcmd_%TABLE_BASE%_get_txt.txt   >> %TABLE_BASE%_select_script.sql
＞type %RES_SQL_DIR%\%TABLE_BASE%_select_get_txt.txt      >> %TABLE_BASE%_select_script.sql
＞echo SPOOL OFF;                                         >> %TABLE_BASE%_select_script.sql
＞echo ;                                                  >> %TABLE_BASE%_select_script.sql
＞echo exit;                                              >> %TABLE_BASE%_select_script.sql
＞
＞rem oracleより、前日の日を取得。
＞
＞sqlplus @%WORK_DIR%\%TABLE_BASE%_select_script.sql

ここで oracleに接続していますね。
この時点で、
%WORK_DIR%\ftpcmd_%TABLE_BASE%_get_doc.txt
%WORK_DIR%\ftpcmd_%TABLE_BASE%_get_txt.txt
の2つのテキストファイルに、ftpで取得するファイルを指定する get (mget?)コマンドが
入っていると思われますね。

＞echo bin                                         >>  ftp_%TABLE_BASE%_get.txt
＞type %WORK_DIR%\ftpcmd_%TABLE_BASE%_get_doc.txt  >>  ftp_%TABLE_BASE%_get.txt
＞echo y                                           >>  ftp_%TABLE_BASE%_get.txt
＞type %WORK_DIR%\ftpcmd_%TABLE_BASE%_get_txt.txt  >>  ftp_%TABLE_BASE%_get.txt
＞echo y                                           >>  ftp_%TABLE_BASE%_get.txt
＞echo ren %TABLE_BASE.doc.Z %TABLE_BASE.doc.Z_end >>  ftp_%TABLE_BASE%_get.txt
＞echo ren %TABLE_BASE.txt %TABLE_BASE.txt_end     >>  ftp_%TABLE_BASE%_get.txt

この記述がおかしいです。
まず環境変数 TABLE_BASE には NS_NDS というフォルダ名が入っているだけで日付なんて入っていないはずです。

更に記述間違いも。%TABLE_BASE は %TABLE_BASE% と書きたかったのでしょう。

echo ren %TABLE_BASE%.doc.Z %TABLE_BASE%.doc.Z_end >>  ftp_%TABLE_BASE%_get.txt
echo ren %TABLE_BASE%.txt %TABLE_BASE%.txt_end     >>  ftp_%TABLE_BASE%_get.txt

この2行が実行されると

echo ren NS_NDS.doc.Z NS_NDS.doc.Z_end >>  ftp_NS_NDS_get.txt
echo ren NS_NDS.txt NS_NDS.txt_end     >>  ftp_NS_NDS_get.txt

と置き換えられますが、日付の入ったファイル名でないのでたぶん rename は失敗します。

このバッチから推測するに、"_end"をつけて rename したい日付の入ったファイルが
どのようなファイル名であるかは実際の所、%WORK_DIR%\ftpcmd_%TABLE_BASE%_get_doc.txt(=E:\taro\abc\model1\worktpcmd_NS_NDS_get_doc.txt)と、%WORK_DIR%\ftpcmd_%TABLE_BASE%_get_txt.txt (=E:\taro\abc\model1\worktpcmd_NS_NDS_get_txt.txt）の中身を見ないとわからないわけです。
たぶん求められている機能は、これらの中身で指定されているファイル全てのファイル名の末尾に _end をつけることでしょう。
そうなるとこれをバッチで解決するためには、
%WORK_DIR%\ftpcmd_%TABLE_BASE%_get_doc.txt
%WORK_DIR%\ftpcmd_%TABLE_BASE%_get_txt.txt
の中にある get コマンドで指定しているファイル名を取得する必要があります。
この2つのファイルの中身がどのような構成になっているかわからないと答えようがありません。

649.	Re16:日付ファイルを毎回リネームしたい 2004年07月15日(木) 15時27分

ori

じゃくさん本当にありがとう御座います

NS_NDS_select_get_doc.txtの中身↓

SELECT 'get NS_NDS_' || TO_CHAR(SYSDATE - 3 , 'YYYYMMDD' ) || '.doc.Z' FROM DUAL;

DT_MBOR_select_get_txt.txtの中身↓

SELECT 'get NS_NDS_' || TO_CHAR(SYSDATE - 3 , 'YYYYMMDD' ) || '.txt' FROM DUAL;

これで日付を管理しているみたいです
-３というのは運用上の決まりみたいです。

＞echo ren %TABLE_BASE%.txt %TABLE_BASE%.txt_end >> ftp_%TABLE_BASE%_get.txt
＞この行が実行されると
＞echo ren NS_NDS.txt NS_NDS.txt_end >> ftp_NS_NDS_get.txt

これを　20040715.doc.Z を　20040715.doc.Z_endにリネームする場合はどうなるのでしょう？

お手数をお掛けいたします。

651.	Re17:日付ファイルを毎回リネームしたい 2004年07月15日(木) 15時59分

じゃく

＞NS_NDS_select_get_doc.txtの中身↓
＞
＞SELECT 'get NS_NDS_' || TO_CHAR(SYSDATE - 3 , 'YYYYMMDD' ) || '.doc.Z' FROM DUAL;
＞
＞
＞DT_MBOR_select_get_txt.txtの中身↓
＞
＞SELECT 'get NS_NDS_' || TO_CHAR(SYSDATE - 3 , 'YYYYMMDD' ) || '.txt' FROM DUAL;
＞
＞これで日付を管理しているみたいです
＞-３というのは運用上の決まりみたいです。

おやおや。そんな気がしていましたが、-3は 3日前の日付を求めているのですよ。

＞
＞＞echo ren %TABLE_BASE%.txt %TABLE_BASE%.txt_end >> ftp_%TABLE_BASE%_get.txt
＞＞この行が実行されると
＞＞echo ren NS_NDS.txt NS_NDS.txt_end >> ftp_NS_NDS_get.txt
＞
＞これを　20040715.doc.Z を　20040715.doc.Z_endにリネームする場合はどうなるのでしょう？

3日前の日付を求めて get しているところをみると事は単純ではありません。

バッチの ftp_%TABLE_BASE%_get.txt を作る部分を以下のようにしてみるとどうでしょう？
（oriさんは実際に試すことのでいる環境があるのでしょうか？）

type %WORK_DIR%\ftpcmd_%TABLE_BASE%_get_doc.txt >> ftp_%TABLE_BASE%_get.txt
echo y >> ftp_%TABLE_BASE%_get.txt
type %WORK_DIR%\ftpcmd_%TABLE_BASE%_get_txt.txt >> ftp_%TABLE_BASE%_get.txt
echo y >> ftp_%TABLE_BASE%_get.txt

for /F "tokens=1,2*" %%a in ( %WORK_DIR%\ftpcmd_%TABLE_BASE%_get_doc.txt ) do (
  if "%%a"=="get" echo rename %%b %%b_end >> ftp_%TABLE_BASE%_get.txt
)
for /F "tokens=1,2*" %%a in ( %WORK_DIR%\ftpcmd_%TABLE_BASE%_get_txt.txt ) do (
  if "%%a"=="get" echo rename %%b %%b_end >> ftp_%TABLE_BASE%_get.txt
)

echo bye >> ftp_%TABLE_BASE%_get.txt

652.	Re18:日付ファイルを毎回リネームしたい 2004年07月15日(木) 16時34分

ori

ありがとう御座います

夕方テストしてみます
また報告いたします　^0^

655.	Re18:日付ファイルを毎回リネームしたい 2004年07月17日(土) 17時27分

ori

こんにちは！

まだリネームのテストはできていません
以前教えていただいた↓の意味をおしえていただけますか？

for /F "tokens=1,2*" %%a in ( %WORK_DIR%\ftpcmd_%TABLE_BASE%_get_doc.txt ) do (
if "%%a"=="get" echo rename %%b %%b_end >> ftp_%TABLE_BASE%_get.txt
)
for /F "tokens=1,2*" %%a in ( %WORK_DIR%\ftpcmd_%TABLE_BASE%_get_txt.txt ) do (
if "%%a"=="get" echo rename %%b %%b_end >> ftp_%TABLE_BASE%_get.txt
)

宜しくお願いします

656.	Re19:日付ファイルを毎回リネームしたい 2004年07月18日(日) 09時28分

じゃく

＞以前教えていただいた↓の意味をおしえていただけますか？
＞
＞for /F "tokens=1,2*" %%a in ( %WORK_DIR%\ftpcmd_%TABLE_BASE%_get_doc.txt ) do (
＞if "%%a"=="get" echo rename %%b %%b_end >> ftp_%TABLE_BASE%_get.txt
＞)
＞for /F "tokens=1,2*" %%a in ( %WORK_DIR%\ftpcmd_%TABLE_BASE%_get_txt.txt ) do (
＞if "%%a"=="get" echo rename %%b %%b_end >> ftp_%TABLE_BASE%_get.txt
＞)

まずは、for /? でヘルプを見て、 for /F の動作について把握してください。
やっていることは、
%WORK_DIR%\ftpcmd_%TABLE_BASE%_get_doc.txt
%WORK_DIR%\ftpcmd_%TABLE_BASE%_get_txt.txt
のなかで、 get (ファイル名) という行から (ファイル名) を
取り出し、 rename (ファイル名) (ファイル名)_end という
行を新たに作って ftp_%TABLE_BASE%_get.txt に書き込んでいます。

●	626.日付ファイルを毎回リネームしたい ori 04/07/14(水) 19:11

627.Re:日付ファイルを毎回リネームしたい　じゃく 04/07/14(水) 19:27

628.Re2:日付ファイルを毎回リネームしたい　ori 04/07/14(水) 19:38

629.Re3:日付ファイルを毎回リネームしたい　じゃく 04/07/14(水) 19:43

630.Re4:日付ファイルを毎回リネームしたい　ori 04/07/14(水) 19:44

631.Re5:日付ファイルを毎回リネームしたい　じゃく 04/07/14(水) 19:54

633.Re6:日付ファイルを毎回リネームしたい　ori 04/07/14(水) 19:55

634.Re6:日付ファイルを毎回リネームしたい　ori 04/07/14(水) 20:01

635.Re7:日付ファイルを毎回リネームしたい　じゃく 04/07/14(水) 20:08

636.Re8:日付ファイルを毎回リネームしたい　ori 04/07/14(水) 20:55

637.Re9:日付ファイルを毎回リネームしたい　じゃく 04/07/14(水) 21:06

638.Re10:日付ファイルを毎回リネームしたい　ori 04/07/14(水) 23:34

643.Re11:日付ファイルを毎回リネームしたい　じゃく 04/07/15(木) 09:24

645.Re12:日付ファイルを毎回リネームしたい　ori 04/07/15(木) 12:09

646.Re13:日付ファイルを毎回リネームしたい　じゃく 04/07/15(木) 13:38

647.Re14:日付ファイルを毎回リネームしたい　ori 04/07/15(木) 14:32

648.Re15:日付ファイルを毎回リネームしたい　じゃく 04/07/15(木) 15:08

649.Re16:日付ファイルを毎回リネームしたい　ori 04/07/15(木) 15:27

651.Re17:日付ファイルを毎回リネームしたい　じゃく 04/07/15(木) 15:59

652.Re18:日付ファイルを毎回リネームしたい　ori 04/07/15(木) 16:34

655.Re18:日付ファイルを毎回リネームしたい　ori 04/07/17(土) 17:27

656.Re19:日付ファイルを毎回リネームしたい　じゃく 04/07/18(日) 09:28

639.Re10:日付ファイルを毎回リネームしたい　ori 04/07/14(水) 23:41

644.Re11:日付ファイルを毎回リネームしたい　じゃく 04/07/15(木) 09:27

632.Re5:日付ファイルを毎回リネームしたい　ori 04/07/14(水) 19:54

DOSプロンプト活用相談室LOG

日付ファイルを毎回リネームしたい

カテゴリー一覧

資料書籍

検索

About