ファイル群のバラバラの名前の中から特定の一文字を削除したい (DOSプロンプト活用相談室LOG)

217.	renでファイル名がバラバラの（拡張子は同じ）ファイルのある特定の一文字を削除したい 2005年01月24日(月) 14時08分

●DOS/Windowsのバージョン↓
WindowsXPです。
初歩的な質問ですいません。
同じディレクトリにある、ファイル名がバラバラの
（拡張子は同じ）複数のファイルのある特定の一文字だけを
renameコマンドで消したいのです。

aaap.txt ccccccp.txt ttttp.txt

↓

aaa.txt cccccc.txt tttt.txt

などというように、「p」を消す作業を一括で行いたのです。
同じ文字数のファイルならばできるのですが、
文字数が違うので、ファイル名を変更する事ができません。

どうぞよろしくお願いいたします。

219.	Re:renでファイル名がバラバラの（拡張子は同じ）ファイルのある特定の一文字を削除したい 2005年01月24日(月) 16時21分

じゃく

＞●DOS/Windowsのバージョン↓
＞WindowsXPです。

＞
＞aaap.txt ccccccp.txt ttttp.txt
＞
＞↓
＞
＞aaa.txt cccccc.txt tttt.txt
＞
＞などというように、「p」を消す作業を一括で行いたのです。
＞同じ文字数のファイルならばできるのですが、
＞文字数が違うので、ファイル名を変更する事ができません。

質問です。
１．上記の例の場合、aapPaap.txt というファイル名があった場合
どのような結果を望まれていますか？
1)aapPaa.txt （ファイル名末尾の1文字の"p"のみ）
2)aaPaa.txt（小文字の"p"はすべて）
2)aaaa.txt（大文字小文字全ての"p"）

拡張子に"p"が含まれていても拡張子はそのままですよね。

２．指定したい条件は何ですか？
・拡張子(txtとかjpg)とか
・消す文字
他に指定したいものはありますか？（フォルダの指定など）

220.	Re2:renでファイル名がバラバラの（拡張子は同じ）ファイルのある特定の一文字を削除したい 2005年01月24日(月) 16時43分

じゃく

自己レスです。
＞2)aaaa.txt（大文字小文字全ての"p"）
は3)の誤りです。

また、この質問の想定として set /?で出てくる環境変数の置換を使おうと思ったのですが、今検証してみたらヘルプにある

%PATH:文字列1=文字列2%

の文法で文字列１は大文字／小文字を区別しないことが判明。
よって、ご希望が2)の場合簡単に対応する方法が思い付かない
かもしれません。1)や3)ならいいのですが。

＞質問です。
＞１．上記の例の場合、aapPaap.txt というファイル名があった場合
＞どのような結果を望まれていますか？
＞1)aapPaa.txt （ファイル名末尾の1文字の"p"のみ）
＞2)aaPaa.txt（小文字の"p"はすべて）
＞2)aaaa.txt（大文字小文字全ての"p"）
＞
＞拡張子に"p"が含まれていても拡張子はそのままですよね。
＞
＞２．指定したい条件は何ですか？
＞・拡張子(txtとかjpg)とか
＞・消す文字
＞他に指定したいものはありますか？（フォルダの指定など）
＞
＞

221.	Re3:renでファイル名がバラバラの（拡張子は同じ）ファイルのある特定の一文字を削除したい 2005年01月24日(月) 17時20分

お返事どうもありがとうございます。

＞の文法で文字列１は大文字／小文字を区別しないことが判明。
＞よって、ご希望が2)の場合簡単に対応する方法が思い付かない
＞かもしれません。1)や3)ならいいのですが。
＞
＞
＞＞質問です。
＞＞１．上記の例の場合、aapPaap.txt というファイル名があった場合
＞＞どのような結果を望まれていますか？
＞＞1)aapPaa.txt （ファイル名末尾の1文字の"p"のみ）
＞＞2)aaPaa.txt（小文字の"p"はすべて）
＞＞2)aaaa.txt（大文字小文字全ての"p"）
＞＞
＞＞拡張子に"p"が含まれていても拡張子はそのままですよね。
＞＞
＞＞２．指定したい条件は何ですか？
＞＞・拡張子(txtとかjpg)とか
＞＞・消す文字
＞＞他に指定したいものはありますか？（フォルダの指定など）

大文字小文字は問いません。
1)と3)のファイル名末尾の1文字のpのみの場合と、
大文字小文字全てのpの場合の両方の場合を教えていただきたいです。

拡張子に"p"が含まれていても拡張子はそのままで、
拡張子は「.jpg」です。
他には特に指定はありません。

お手数をかけますがどうぞよろしくお願いいたします。

222.	Re4:renでファイル名がバラバラの（拡張子は同じ）ファイルのある特定の一文字を削除したい 2005年01月24日(月) 18時01分

otn

＞大文字小文字は問いません。
＞1)と3)のファイル名末尾の1文字のpのみの場合と、
＞大文字小文字全てのpの場合の両方の場合を教えていただきたいです。
＞
＞拡張子に"p"が含まれていても拡張子はそのままで、
＞拡張子は「.jpg」です。
＞他には特に指定はありません。
＞
＞お手数をかけますがどうぞよろしくお願いいたします。

本筋の回答は、じゃくさんにおまかせするとして、一度しかやらないのなら、
(for %F in (*.jpg) do @echo REN %F %F;)>R.BAT

とリネームをするバッチファイルを作ることにして、メモ帳等のエディタでR.BATを好きなように編集してから実行するという手もあります。

1) ならエディタで p.jpg; を .jpg に全置換
3) ならエディタで第二パラメータの部分の p や P を削除(メモ帳だと手作業になりつらいですが)

全置換に便利なようにセミコロンを書きましたが、RENはセミコロンを無視しますので残っても削除しなくて構いません。

223.	Re5:renでファイル名がバラバラの（拡張子は同じ）ファイルのある特定の一文字を削除したい 2005年01月24日(月) 18時49分

じゃく

Maさん、otnさん、こんにちは。

＞＞大文字小文字は問いません。
＞＞1)と3)のファイル名末尾の1文字のpのみの場合と、
＞＞大文字小文字全てのpの場合の両方の場合を教えていただきたいです。
＞＞
＞＞拡張子に"p"が含まれていても拡張子はそのままで、
＞＞拡張子は「.jpg」です。
＞＞他には特に指定はありません。
＞＞
＞＞お手数をかけますがどうぞよろしくお願いいたします。
＞
＞本筋の回答は、じゃくさんにおまかせするとして、一度しかやらないのなら、

otnさん、ご配慮ありがとうございます。(^^)

1)ファイル名の末尾1文字がpでかつ、pを取り除く場合を
考えてみました。
-------------------------------------ren1.bat
setlocal ENABLEDELAYEDEXPANSION

:末尾の1文字の指定
set char=p
:拡張子の指定
set ext=jpg

for %%f in ( *%char%.%ext% ) do (
    set fname=%%~nf
    set fname=!fname:~0,-1!
    ren %%f !fname!.%ext%
)

------------------------------------------------

3)つぎに、ファイル名に含まれるp(大文字、小文字とも）を
取り除く場合について考えてみました。
--------------------------------------------renall.bat
setlocal ENABLEDELAYEDEXPANSION

:削除する文字の指定
set char=p
:拡張子の指定
set ext=jpg

for %%f in ( *.%ext% ) do (
    set fname=%%~nf
    set fname=!fname:%char%=!
    ren %%f !fname!.%ext%
)

------------------------------------------------

この場合、ファイルの末尾がpでない場合もリネームするように
していますので、末尾がp(=削除する文字）に限定する場合は
for %%f in ( *.%ext% ) do (
を
for %%f in ( *%char%.%ext% ) do (
に変更します。

224.	Re6:renでファイル名がバラバラの（拡張子は同じ）ファイルのある特定の一文字を削除したい 2005年01月24日(月) 19時19分

じゃくさん、otnさん、色々ありがとうございます。
たった今試してみましたところ、見事にできました！

本や色々なページを見ながらいろいろな事を試していたのですが
簡単なことしかできなくて、今日お聞きした事についても、
出来るだけ調べて色々試してみたのですが、結局できなかったので書き込みしました。

今から教えてもらった事を一つ一つ調べてみようと思います。
それにしてもコマンドプロンプトはとても便利ですね。

本当に色々ありがとうございました！　　Ma

DOSプロンプト活用相談室LOG

ファイル群のバラバラの名前の中から特定の一文字を削除したい

カテゴリー一覧

資料書籍

検索

About