[9x系]ユーザー名、VERの結果、PC名、HOST名、日時の取得 (DOSプロンプト活用相談室LOG)

806.	[9x系]ファイル連結で改行しない方法（Host名の取得） 2005年10月18日(火) 17時01分

atawi

●DOS/Windowsのバージョン↓

Windows 95, 98, Me

過去ログ等参照させていただいた上での投稿です。
長くなるかもしれませんがよろしくお願いいたします。

9x系のOSでコンピューター名やホスト名を取得する方法について、NET CONFIG や PING を使う方法が過去ログにありましたが、"\\"やFQDN形式で取得されてしまいます。
また、取得した上記値のテキスト編集も9x系では、 FOR コマンドに "/F" オプションが使えないため、うまくいきません。

そこで、レジストリの内容を書き出す方法を考えました。9x系で実行すると、ホスト名と同名のテキストファイルを作成します。

***** GetHostName.batの内容 *****
@ECHO OFF
REGEDIT /E %TEMP%\HOSTNAME.TXT HKEY_LOCAL_MACHINE\System\CurrentControlSet\Services\VxD\MSTCP
CHOICE /c:1 /t:1,5>NUL
FIND "HostName" <%TEMP%\HOSTNAME.txt>%TEMP%\BBB.txt
COPY /B SET.txt+%TEMP%\BBB.txt %TEMP%\CCC.bat>NUL
CALL %TEMP%\CCC.BAT
ECHO %"HostName"% >%"HostName"%.txt

DEL %TEMP%\HOSTNAME.txt
DEL %TEMP%\BBB.txt
DEL %TEMP%\CCC.bat
***** GetHostName.batの内容ここまで *****

***** SET.txtの内容 *****
SET
***** SET.txtの内容ここまで *****

※SET.txtの内容は、SET+半角スペース ※改行なしです。

上記二つのファイルを同じ場所に保存して実行すれば、ホスト名と同名のファイルが作られ、ダブルクォーテーションで括られた、"HostName"　が記述されます。

さて実現したいことは…

1). SET.txtをあらかじめ準備せずbat単体で同じ動作をしたい。
2). テキスト内のダブルクォーテーションを外すことはできるか。

※長くなってもいいのでSedなどのツールは使わない前提で…

1). は、ファイルの連結の際に改行されてしまい悩んでいます。
COPY /B, TYPE, ECHO コマンドなどを検討しましたが、うまくいきませんでした。

可能でしょうか？
不可能です！　という引導を渡していただくだけでも構いません。
何卒よろしくお願いいたします。

807.	Re:[9x系]ファイル連結で改行しない方法（Host名の取得） 2005年10月19日(水) 09時11分

ラシャン

１は思いつきませんでしたが、set.txtを共有サーバー等に置いて
参照するなりコピーしてくるなりする方法もあるかなと思います。

２は、以下のような感じでどうでしょう？

@ECHO OFF
MD %TEMP%\HOSTNAME
REGEDIT /E %TEMP%\HOSTNAME.TXT HKEY_LOCAL_MACHINE\System\CurrentControlSet\Services\VxD\MSTCP
CHOICE /c:1 /t:1,5>NUL
FIND "HostName" <%TEMP%\HOSTNAME.txt>%TEMP%\BBB.txt
COPY /B SET.txt+%TEMP%\BBB.txt %TEMP%\CCC.bat>NUL
CALL %TEMP%\CCC.BAT
ECHO %"HostName"% >%TEMP%\HOSTNAME\%"HostName"%
DIR /B %TEMP%\HOSTNAME>%"HostName"%.txt

DEL %TEMP%\HOSTNAME.txt
DEL %TEMP%\BBB.txt
DEL %TEMP%\CCC.bat
DEL %TEMP%\HOSTNAME\%"HostName"%
RD %TEMP%\HOSTNAME

810.	Re:[9x系]ファイル連結で改行しない方法（Host名の取得） 2005年10月19日(水) 13時03分

otn

>１は思いつきませんでしたが、set.txtを共有サーバー等に置いて
>参照するなりコピーしてくるなりする方法もあるかなと思います。

最後の手段、debug を使いましょうか。

echo rcx >debug.txt
echo 4 >>debug.txt
echo e 100 "SET " >>debug.txt
echo w >>debug.txt
echo q >>debug.txt
debug set.txt < debug.txt

>２は、以下のような感じでどうでしょう？

ナイス。

あと、Win9x系で細かいことをやるなら、アセンブラないしLSI-Cとかでプログラムを書いて、テキスト化してバッチファイルに埋め込むというやりかたもあります。
http://www.asahi-net.or.jp/~bi3t-aoym/nidetool.htm

812.	Re:[9x系]ファイル連結で改行しない方法（Host名の取得） 2005年10月19日(水) 17時13分

atawi

ラシャンさん、otnさん。
回答ありがとうございます。
今回の件で、かなり経験値が上がった感じがします。
今後、色々と応用できそうで、DOSのバッチファイルで
できなかったことが色々実現可能になりそうです。
クライアントの管理に有効活用させていただきます。

＞ラシャンさん

>１は思いつきませんでしたが、set.txtを共有サーバー等に置いて
>参照するなりコピーしてくるなりする方法もあるかなと思います。

目的を達するだけなら、全くその通りなんですが、
何か悔しい、というか、すっきりしなかったので。
こんな方法もある、という情報を探していました。

>２は、以下のような感じでどうでしょう？

otnさんのコメントにもありますが、本当にナイスです。
ダブルクォーテーションなしのファイルを作成できたとき、
（そもそもファイル名には " が使用できないことを利用）
何となく Dir も頭に浮かんだのですが、
この結果に結びつきませんでした。

頭のモヤモヤが晴れた感じでちょっと感動。

＞otnさん。

debug.exeは、ここでちょっと調べました。
http://www.ncfreak.com/cecilia/hamatu/2002.09.html

プログラム経験がほとんどないのですが、
debug.exeがアセンブラとして使えるので、
ファイルの生成にも使える、ということなのですね。

なぜカウントレジスタというものを使うのか？　など、
根本的なことは全くわからないのですが、

カウンタレジスタを宣言
4バイトを確保
アドレス100から、"SET "を入力
書き込み
終了
上記をファイル名SET.txtを指定して実行

という流れでファイルの生成ができるのだろう、
ということをなんとなく推測しました。

なぜ、debug.exeみたいなファイルが最新OSにも存在しているのか、
しかも起動ディスクにまで含まれているのか不思議でしたが、
これを呼び出して利用する場面もあるということなのでしょうね。

これも色々と応用が利きそうです。ありがとうございました。

P.S.
整理されたものが出来上がったら、
参考までに最後にレスしておく予定です。

815.	debug.exeを利用したテキストファイルの出力について 2005年10月20日(木) 19時17分

atawi

ここで教えていただいた内容とは言え、
バッチではなく、debug.exeについてなので、
ここで質問してよいものか迷いますが…

otn様差し支えなければお分かりになる範囲で教えてください。

debug.exeでテキストファイルを出力するというのは、
本当に最後の手段で若干裏技的なのかもしれませんし、
特にバイナリレベルで書き換えるものでしょうから、
理解できないなら多用するべきではないのかもしれませんが、
以下のような状態になります。

出力するテキストが9バイトまでなら問題なし。
10バイトを超えるサイズを以下のように指定した場合、

ECHO rcx >debug.txt
ECHO 13 >>debug.txt
ECHO e 100 "SET username=" >>debug.txt
ECHO w >>debug.txt
ECHO q >>debug.txt
DEBUG SET.TXT < debug.txt

1). ごみが末尾についてしまう
例：SET username=翰u

d でダンプして空いていそうなアドレス 90 などに書いて、アドレスの先頭を w 90 などと指定して書き出した場合、

ECHO rcx >debug.txt
ECHO 13 >>debug.txt
ECHO e 90 "SET username=" >>debug.txt
ECHO w 90 >>debug.txt
ECHO q >>debug.txt
DEBUG SET.TXT < debug.txt

2). 19文字出力されてしまう（指定文字以降スペースが入る）
例：SET username= ←ここまでスペース

などのようになります。
プログラミングの解説をここで詳しくしていただくつもりはありませんが、
今回の目的に沿ってアドバイスいただければ幸いです。

816.	Re:debug.exeを利用したテキストファイルの出力について 2005年10月21日(金) 10時11分

じゃく

こんにちは

>出力するテキストが9バイトまでなら問題なし。
>10バイトを超えるサイズを以下のように指定した場合、
>
>ECHO rcx >debug.txt
>ECHO 13 >>debug.txt
>ECHO e 100 "SET username=" >>debug.txt
>ECHO w >>debug.txt
>ECHO q >>debug.txt
>DEBUG SET.TXT < debug.txt
>
>1). ごみが末尾についてしまう
>例：SET username=翰u
>
debug.exeを詳しく知りませんが、指定している13が16進数として扱われていると思います。

googleで検索したら以下のページに
＞なお、DEBUGでは数値はすべて１６進数表記です。後ろにHをつけませんが、１６進数なので、ご注意を。
という表記を見つけました。

http://kasai86.ld.infoseek.co.jp/asm/asm2.htm

0x13=19バイト
13バイトなら'0D'にしてみては？
>ECHO 0D >>debug.txt

817.	Re:debug.exeを利用したテキストファイルの出力について 2005年10月21日(金) 15時52分

atawi

>指定している13が16進数として扱われていると思います。

"大変"お恥ずかしい。全くそのとおりでした。
結果として 0D または単に D でもOKでした。

9 までがOKで 10 以降が NG という点で、
すぐに気がつかなければいけませんでした。というか、
そもそもプログラムの世界なら16進数使って当たり前だし、
ダンプしたら16進ダンプが表示されたにもかかわらず…（泣）

http://www.shuiren.org/chuden/teach/code/main1.htm#16
http://www.algolab.co.jp/~lum/pcnyumon/nyu031.htm

経験もなく何も知らないというのは怖いものです。

ちなみに、0D か 0 かなどの記述法については、
google検索で、以下のような記述を見つけました。
私も 0D のように記述したいと思います。

http://www.wo-man.org/~reiko/math/06.html

>9の次はAHとなるところでしょうが、慣習的に頭に“0”をつけます。理由は、80系のアセンブラにはAH、BH、……というレジスタがあるので、アセンブラコードではなく数字だということを表わすためだ、と聞いたことがありますが、ちょっと自信はありません。

今度こそ、うまくいきそうです！
皆さんありがとうございました。

818.	Re:debug.exeを利用したテキストファイルの出力について 2005年10月21日(金) 15時58分

YanaKen◆c0rnJ1Q=

atawiさん　こんにちは。

>ここで教えていただいた内容とは言え、
>バッチではなく、debug.exeについてなので、
>ここで質問してよいものか迷いますが…

　debugのような、コマンド・プロンプト上での利用(バッチ処理を含む)前提の、OSに標準でついてくるコマンドの活用相談は、完全にこの掲示板が扱うテーマの範囲内ですので、書き込みを遠慮される方がいらっしゃると運営者は逆に悩むことになります(^^;。
　ご遠慮なくお願いします。

Manager YanaKen

819.	Re:debug.exeを利用したテキストファイルの出力について 2005年10月21日(金) 18時17分

otn

otnです。

>>指定している13が16進数として扱われていると思います。

解決したようで良かったです。
私もずいぶん忘れていました。先の投稿のやり方だと、debug 実行時に、SET.TXTが無いので「ファイルが見つかりません」と出るはず。

ECHO rcx >debug.txt
ECHO 0d >>debug.txt
ECHO e 100 "SET username=" >>debug.txt
ECHO nSET.TXT>>debug.txt
ECHO w >>debug.txt
ECHO q >>debug.txt
DEBUG < debug.txt
と、nサブコマンドでファイル名を指定するべきでした。

あるいは、
ECHO SET usernam>SET.TXT
ECHO e 100 "SET username=" >debug.txt
ECHO w >>debug.txt
ECHO q >>debug.txt
DEBUG SET.TXT < debug.txt
と、最初にCRLF含めて13バイトのファイルを作っておけば、ファイルの長さを示すCXレジスタに000Dが入った状態で起動されますので、RCXコマンドで長さをセットする必要がありません。

この場合、e 100 のところは、e 10B "e=" でもＯＫ。

820.	Re:debug.exeを利用したテキストファイルの出力について 2005年10月21日(金) 19時45分

じゃく

みなさん、こんばんは。
もうdebug.exe でうまくいっているようなのですが、
バッチの最後がexitでcommand.comを終わっていいのなら
バッチ自身の最後にSET.txt 相当をつけておくという方法はできませんかねぇ。（当方 Win9X系の環境がないので検証できないのです）

@ECHO OFF
IF "%1"=="SET" goto setenv
REGEDIT /E %TEMP%\HOSTNAME.TXT HKEY_LOCAL_MACHINE\System\CurrentControlSet\Services\VxD\MSTCP
CHOICE /c:1 /t:1,5>NUL
FIND "HostName" <%TEMP%\HOSTNAME.txt>%TEMP%\BBB.txt
COPY /B %0+%TEMP%\BBB.txt %TEMP%\CCC.bat>NUL
CALL %TEMP%\CCC.BAT SET
ECHO %"HostName"% >%"HostName"%.txt

DEL %TEMP%\HOSTNAME.txt
DEL %TEMP%\BBB.txt
DEL %TEMP%\CCC.bat
exit

:setenv
SET (もちろんここは改行しない）

821.	Re:debug.exeを利用したテキストファイルの出力について 2005年10月22日(土) 01時54分

atawi

otn様

回答ありがとうございました。

>ECHO nSET.TXT>>debug.txt

n で名前付けをするのは、debug を起動して、
1行づつコマンドの意味を調べているとき気がつきました。
エラーは出ますがファイルの出力はされるので、
そんなものかと思っていましたが・・・
一応 ECHO で事前にファイルを作って回避することを考えていました。
でもこうやって n で指定するのがセオリーっぽくていいですね。

じゃく様

今までは実行すると、上から下へそのまま流れていくような、
単純なバッチばかり書いてきたので、今回も、
debug.exeを使用する方法で書いていたのですが・・・

私もWin9x系の環境が今、自宅にないので、
XP上で、適当に内容を書き換えた上で、
1行ずつPAUSEかけて実行してみました。

おおなるほど～　こういう発想のバッチを書くのは、
実は結構苦手ですが・・・　すごいですね。
特別なコマンドを利用しなくても、
工夫しだいでここまでできるとは・・・

どうやら問題なく動きそうですが、
XP では、"" を含んだ環境変数は、
どうやら設定できないようです。

したがって詳細な確認は、都合で来週火曜日以降になりそうです。

また、シスオペのYanaKen様より、
掲示板で扱うテーマ範囲のご案内も頂きましたので、
安心して利用させていただきます。
ご丁寧にありがとうございました。
今後ともよろしくお願いいたします。

822.	Re:debug.exeを利用したテキストファイルの出力について 2005年10月22日(土) 14時28分

otn

>おおなるほど～　こういう発想のバッチを書くのは、
>実は結構苦手ですが・・・　すごいですね。
>特別なコマンドを利用しなくても、
>工夫しだいでここまでできるとは・・・

%0 を使うので、起動時には、aaa.bat のように拡張子まで指定する必要があります。初心者に「手順書通り打て」というのなら大丈夫でしょうが、生半可なひとがいて、.bat を省略すると、スクリプトは起動するものの、ファイルが無いのでエラーになります。
念のため、if exist %0 で存在しなければ %0.bat を使うようにしたほうが良いと思います。

>XP では、"" を含んだ環境変数は、
>どうやら設定できないようです。

はい。そうですが、
command /E:5000 /C aaa.bat
等ととすることである程度の確認は出来ます。

830.	[9x系]ユーザー名、VERの結果、PC名、HOST名、日時の取得 2005年10月25日(火) 21時24分

atawi

色々と教えていただいた情報及び、日時の取得に関してはじゃく様のWEB上の情報
http://homepage1.nifty.com/jak/batch/time.html
を参考にさせていただき、以下のバッチを作成しました。

9x系（95, 98, Meで確認）のOSで実行すると、%TEMP%フォルダに、HOST名と同名のファイルを作り、カンマ区切りで、ユーザー名、VERの結果、PC名、HOST名、日時を出力します。ファイルの出力先は任意のものに変更してください。

SETコマンドの作成用一時ファイルは、otn様の情報（バッチ自身の最後にSET.txt 相当をつけておくという方法）で、きちんと作成されることを確認しましたが、今回は複数ファイルを作成する必要があり、少々複雑になりそうだったので、冗長ではありますがdebug.exeを使用する方法で作成させていただきました。

***** GetPcInfo.bat *****

@ECHO OFF
PROMPT $H

REM ***** Win9x系の以下の情報をホスト名と同名のファイルに書き出す *****
REM ***** ・ユーザー名
REM ***** ・VERコマンドの結果
REM ***** ・コンピューター名
REM ***** ・ホスト名
REM ***** ・このバッチの実行日時
REM *****

REM ***** SETコマンドを記述したファイルをあらかじめ作成 *****
ECHO rcx >%TEMP%\TMP0.100
ECHO 4 >>%TEMP%\TMP0.100
ECHO e 100 "SET " >>%TEMP%\TMP0.100
ECHO n%TEMP%\SET.SET >>%TEMP%\TMP0.100
ECHO w >>%TEMP%\TMP0.100
ECHO q >>%TEMP%\TMP0.100
DEBUG < %TEMP%\TMP0.100 >NUL

ECHO rcx >%TEMP%\TMP0.100
ECHO 8 >>%TEMP%\TMP0.100
ECHO e 100 "SET VER=" >>%TEMP%\TMP0.100
ECHO n%TEMP%\SET.VER >>%TEMP%\TMP0.100
ECHO w >>%TEMP%\TMP0.100
ECHO q >>%TEMP%\TMP0.100
DEBUG < %TEMP%\TMP0.100 >NUL

ECHO rcx >%TEMP%\TMP0.100
ECHO 0D >>%TEMP%\TMP0.100
ECHO e 100 "SET username=" >>%TEMP%\TMP0.100
ECHO n%TEMP%\SET0.000 >>%TEMP%\TMP0.100
ECHO w >>%TEMP%\TMP0.100
ECHO q >>%TEMP%\TMP0.100
DEBUG < %TEMP%\TMP0.100 >NUL

ECHO rcx >%TEMP%\TMP0.100
ECHO 11 >>%TEMP%\TMP0.100
ECHO e 100 "SET ComputerName=" >>%TEMP%\TMP0.100
ECHO n%TEMP%\SET2.000 >>%TEMP%\TMP0.100
ECHO w >>%TEMP%\TMP0.100
ECHO q >>%TEMP%\TMP0.100
DEBUG < %TEMP%\TMP0.100 >NUL

ECHO rcx >%TEMP%\TMP0.100
ECHO 0D >>%TEMP%\TMP0.100
ECHO e 100 "SET HostName=" >>%TEMP%\TMP0.100
ECHO n%TEMP%\SET3.000 >>%TEMP%\TMP0.100
ECHO w >>%TEMP%\TMP0.100
ECHO q >>%TEMP%\TMP0.100
DEBUG < %TEMP%\TMP0.100 >NUL

REM ***** レジストリの内容をファイルに書き出す *****
REGEDIT /E %TEMP%\TMP0.000 HKEY_LOCAL_MACHINE\Network\Logon
VER >%TEMP%\TMP1.000
REGEDIT /E %TEMP%\TMP2.000 HKEY_LOCAL_MACHINE\System\CurrentControlSet\Services\VxD\VNETSUP
REGEDIT /E %TEMP%\TMP3.000 HKEY_LOCAL_MACHINE\System\CurrentControlSet\Services\VxD\MSTCP

REM ***** 実行速度の遅いPCのため、15秒待ち *****
CHOICE /c:1 /t:1,15>NUL

REM ***** 対象の文字列を含む行をファイルに書き出す *****
FIND "username" <%TEMP%\TMP0.000>%TEMP%\TMP0.001
FIND "Windows" <%TEMP%\TMP1.000>%TEMP%\TMP1.001
FIND "ComputerName" <%TEMP%\TMP2.000>%TEMP%\TMP2.001
FIND "HostName" <%TEMP%\TMP3.000>%TEMP%\TMP3.001

REM ***** ファイルをバッチファイルとして結合 *****
COPY /B %TEMP%\SET.SET+%TEMP%\TMP0.001 %TEMP%\TMP0.bat>NUL
COPY /B %TEMP%\SET.VER+%TEMP%\TMP1.001 %TEMP%\TMP1.bat>NUL
COPY /B %TEMP%\SET.SET+%TEMP%\TMP2.001 %TEMP%\TMP2.bat>NUL
COPY /B %TEMP%\SET.SET+%TEMP%\TMP3.001 %TEMP%\TMP3.bat>NUL

REM ***** バッチファイルを実行して環境変数を設定 *****
CALL %TEMP%\TMP0.bat
CALL %TEMP%\TMP1.bat
CALL %TEMP%\TMP2.bat
CALL %TEMP%\TMP3.bat

REM ***** "" を外す処理（設定した環境変数をファイル名として出力） *****
ECHO %"username"% >%TEMP%\%"username"%

ECHO %"ComputerName"% >%TEMP%\%"ComputerName"%
ECHO %"HostName"% >%TEMP%\%"HostName"%

REM ***** "" を外す処理（設定した環境変数をファイル名として出力） *****
DIR %TEMP%\%"username"% /B >%TEMP%\TMP0.002

DIR %TEMP%\%"ComputerName"% /B >%TEMP%\TMP2.002
DIR %TEMP%\%"HostName"% /B >%TEMP%\TMP3.002

REM ***** "" のついた環境変数を空にする *****
SET "username"=

SET "ComputerName"=
SET "HostName"=

REM ***** ファイルをバッチファイルとして結合 *****
COPY /B %TEMP%\SET0.000+%TEMP%\TMP0.002 %TEMP%\TMP0.bat>NUL

COPY /B %TEMP%\SET2.000+%TEMP%\TMP2.002 %TEMP%\TMP2.bat>NUL
COPY /B %TEMP%\SET3.000+%TEMP%\TMP3.002 %TEMP%\TMP3.bat>NUL

REM ***** バッチファイルを実行して環境変数を設定 *****
CALL %TEMP%\TMP0.bat

CALL %TEMP%\TMP2.bat
CALL %TEMP%\TMP3.bat

REM ***** 日時を環境変数に設定 *****
ECHO SET DATE=%%3> %TEMP%\TMP4.bat
ECHO SET TIME=%%4>>%TEMP%\TMP4.bat
DIR %TEMP%\TMP4.bat | FIND "TMP4" > %TEMP%\TMP5.bat
CD %TEMP%
CALL %TEMP%\TMP5.bat

REM ***** 環境変数の内容を表示（動作確認用） *****
REM SET
REM PAUSE

REM ***** 設定した環境変数をHost名と同名のファイルに書き出す *****
ECHO %username%,%Ver%,%ComputerName%,%HostName%,%DATE% %TIME%,>%HostName%.txt

REM ***** 一時ファイルを削除 *****
DEL %TEMP%\SET.*
DEL %TEMP%\SET?.*
DEL %TEMP%\TMP?.*
DEL %TEMP%\%username%
DEL %TEMP%\%ComputerName%
IF EXIST %TEMP%\%HostName% DEL %TEMP%\%HostName%

REM ***** 出力されたファイルを以下のコマンドで集計可能 *****
REM "FOR %%A IN (*.TXT) DO TYPE %%A >>Kekka.csv"

833.	Re:[9x系]ユーザー名、VERの結果、PC名、HOST名、日時の取得 2005年10月31日(月) 16時57分

atawi

一部修正します。下記の部分ですが、
末尾に CD %Windir% を追加します。

ログオンスクリプトで実行させた場合、
規定のカレントディレクトリ %Windir% に復帰させておかないと、
ログオンスクリプトが終了後もデスクトップが
表示されない問題がありました。

REM ***** 日時を環境変数に設定 *****
ECHO SET DATE=%%3> %TEMP%\TMP4.bat
ECHO SET TIME=%%4>>%TEMP%\TMP4.bat
DIR %TEMP%\TMP4.bat | FIND "TMP4" > %TEMP%\TMP5.bat
CD %TEMP%
CALL %TEMP%\TMP5.bat
CD %Windir%

●	806.[9x系]ファイル連結で改行しない方法（Host名の取得） atawi 05/10/18(火) 17:01

807.Re:[9x系]ファイル連結で改行しない方法（Host名の取得）　ラシャン 05/10/19(水) 09:11

810.Re:[9x系]ファイル連結で改行しない方法（Host名の取得）　otn 05/10/19(水) 13:03

812.Re:[9x系]ファイル連結で改行しない方法（Host名の取得）　atawi 05/10/19(水) 17:13

815.debug.exeを利用したテキストファイルの出力について　atawi 05/10/20(木) 19:17

816.Re:debug.exeを利用したテキストファイルの出力について　じゃく 05/10/21(金) 10:11

817.Re:debug.exeを利用したテキストファイルの出力について　atawi 05/10/21(金) 15:52

819.Re:debug.exeを利用したテキストファイルの出力について　otn 05/10/21(金) 18:17

820.Re:debug.exeを利用したテキストファイルの出力について　じゃく 05/10/21(金) 19:45

821.Re:debug.exeを利用したテキストファイルの出力について　atawi 05/10/22(土) 01:54

822.Re:debug.exeを利用したテキストファイルの出力について　otn 05/10/22(土) 14:28

818.Re:debug.exeを利用したテキストファイルの出力について　YanaKen◆c0rnJ1Q= 05/10/21(金) 15:58

830.[9x系]ユーザー名、VERの結果、PC名、HOST名、日時の取得　atawi 05/10/25(火) 21:24

833.Re:[9x系]ユーザー名、VERの結果、PC名、HOST名、日時の取得　atawi 05/10/31(月) 16:57

日時: 2005年10月18日 13:04 | この記事のURL

DOSプロンプト活用相談室LOG

[9x系]ユーザー名、VERの結果、PC名、HOST名、日時の取得

カテゴリー一覧

資料書籍

検索

About